home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 090 / pctj8504.arc / SMALL.ASM < prev    next >
Assembly Source File  |  1986-09-14  |  2KB  |  76 lines
  1. Page    60,132 
  2. Title    SMALL -- Load EGA 8x8 Font for 25 or 43 Line Screens
  3.  
  4. Subttl    Thomas V. Hoffmann, January 1985 
  5.  
  6. ;--This program selects 80x25 alpha color mode (mode 3), loads the 
  7. ;  EGA character generator with the 8x8 font, and causes BIOS to 
  8. ;  recalculate the video parameters for maximum screen dimensions.
  9. ; 
  10. ;  With 350-line displays, this gives 43 lines per screen. 
  11. ;  With 200-line displays, this gives 25 lines per screen. 
  12. ; 
  13.  
  14. Stack    segment    para stack 'stack' 
  15.     dw    64 dup (0) 
  16. Stack    Ends 
  17.  
  18. Bdata    segment at 40H          ;-- BIOS data segment 
  19.     org    63H 
  20. CRTC    dw    ?         ; Base I/O address of CRTC 
  21.     org    87H 
  22. info    db    ?         ; Bit 0=1 inhibits cursor emulation 
  23. Bdata    Ends 
  24.  
  25. Code    segment    para public 'code' 
  26. Small    proc    far 
  27.     Push    es         ; Push ES:0 for return to DOS 
  28.     Sub    ax,ax 
  29.      Push    ax 
  30.     Mov    ax,Bdata    ; Set DS to BIOS data segment 
  31.     Mov    ds,ax 
  32.      assume    ds:Bdata 
  33.  
  34.     Mov    ax,0003H    ; Set 80-column alpha mode 
  35.     Int    10H 
  36.  
  37.     Mov    ax,1112H    ; Load 8x8 font 
  38.     Mov    bl,0         ;   into block 0 
  39.     Int    10H         ;   and recalc screen 
  40.  
  41. ; This code sets the EGA CRTC cursor register directly, after
  42. ; inhibiting the BIOS cursor emulation function.  On 350-line
  43. ; displays, this prevents BIOS from setting the cursor to lines
  44. ; 11 and 12, which are not displayed for 8-line characters.
  45.  
  46.     Or    info,1         ; Inhibit cursor emulation 
  47.     Mov    ax,0100H    ; Set cursor 
  48.     Mov    bh,0         ;   for page 0 
  49.     Mov    cx,0600H    ;   to last two lines 
  50.      Int    10H         ;    (start on 6, off on 0) 
  51. page 
  52.  
  53. ; This code sets the underline location register in the CRTC to 
  54. ; the last line of the character box (line 7).  BIOS incorrectly
  55. ; sets it to line 8, which is not displayed. 
  56.  
  57.     Mov    dx,CRTC         ; Get CRTC base address 
  58.     Mov    al,14H         ; Select underline loc register 
  59.     Out    dx,al 
  60.     Inc    dx         ; Point DX to CRTC data register 
  61.     Mov    al,7         ; Set underline loc to line 7 
  62.     Out    dx,al 
  63.  
  64. ; This code enables the EGA BIOS print screen routine, which
  65. ; can handle non-standard display dimensions.  In this case
  66. ; it handles 43 lines of characters on 350-line displays. 
  67.  
  68.     Mov    ax,1200H    ; Select EGA screen print 
  69.     Mov    bl,20H         ;   routine 
  70.     Int    10H 
  71.  
  72.     Ret              ; Return to DOS 
  73. Small    Endp 
  74. Code    Ends 
  75.     End 
  76.